group 'net.pingex'

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'maven-publish'
apply plugin: "com.zoltu.git-versioning"

sourceCompatibility = 1.8

repositories {
    mavenCentral()
    jcenter()
    maven {
        url  "https://jitpack.io"
    }
}

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "gradle.plugin.com.zoltu.gradle.plugin:git-versioning:2.0.12"
    }
}

dependencies {
    // Logging
    compile group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.6.1'
    compile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.6.1'
    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.21' // D4J Logger routing
    compile group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.6.1' // D4J Logger routing

    // Configuration framework
    compile group: 'org.apache.commons', name: 'commons-configuration2', version: '2.0'
    compile group: 'commons-beanutils', name: 'commons-beanutils', version: '1.9.2'

    // Discord Gateway API
    compile group: 'com.github.austinv11', name: 'Discord4j', version: '2.7.0'

    // Util
    compile group: 'net.jodah', name: 'failsafe', version: '0.8.3'

    // Permissions
    compile group: 'org.mapdb', name: 'mapdb', version: '3.0.1'

    testCompile group: 'junit', name: 'junit', version: '4.11'
}

jar {
    manifest {
        attributes 'Implementation-Title': 'DiscordCommandableFramework',
                'Main-Class': 'net.pingex.dcf.DiscordCommandableFramework'
    }
}

task runtimeJar(type: Jar) {
    classifier = 'runtime'
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}

task sourcesJar(type: Jar, dependsOn: 'classes') {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: 'javadoc') {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives jar
    archives runtimeJar
    archives sourcesJar
    archives javadocJar
}

publishing {
    publications {
        mavenJava(MavenPublication){
            from components.java

            artifact jar
            artifact runtimeJar
            artifact sourcesJar
            artifact javadocJar
        }
    }
}